* Wealth index calculation. Hanna Useem, 09/09/2024. Zambia DHS 2024.
cd 'C:\ZM81\Wealth'.
include file='wealth_assets.sps'.
missing values QH131 (99.9).
execute.
set tvars=both.

* Macro definitions to perform some recoding automatically.
* Note: Do not use an asterisk in front of a macro name to try to comment it out - it will run any way because of the way the macros are expanded.
* Delete the line instead or change the spelling of the macro in the comment.
* Do not use the names of macros in comments - they will also be expanded too, and likely will fail.

*{Create binary variables based on condition and give label }.
define dichotomize( !positional !enclose('(',')') / !positional !tokens(1) / !positional !tokens(1) )
compute !2=0.
if (!1) !2=1.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*(Separate shared toilets from non-shared toilets).
define shared_fac( !positional !tokens(1) / !positional !tokens(1) / !positional !tokens(1) ).
compute !2 = 0.
do if (QH110=1).
+ if (!1=1) !2 = 1.
+ compute !1 = 0.
end if.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*{Reset missing values to 'does not have', change 2 code to 0}.
define no2zero( !positional !tokens(1) )
if (missing(!1) | !1<>1) !1=0.
value labels !1 0 'No' 1 'Yes'.
!enddefine.

*{Construct Variables}.

* Source of drinking water.
dichotomize (QH101=11) QH101_11 "Source of drinking water: Piped into dwelling".
dichotomize (QH101=12) QH101_12 "Source of drinking water: Piped to yard/plot".
dichotomize (QH101=13) QH101_13 "Source of drinking water: Piped to neighbor".
dichotomize (QH101=14) QH101_14 "Source of drinking water: Public tap/standpipe".
dichotomize (QH101=21) QH101_21 "Source of drinking water: Borehole".
dichotomize (QH101=31) QH101_31 "Source of drinking water: Protected well".
dichotomize (QH101=32) QH101_32 "Source of drinking water: Unprotected well".
dichotomize (QH101=41) QH101_41 "Source of drinking water: Protected spring".
dichotomize (QH101=42) QH101_42 "Source of drinking water: Unprotected spring".
dichotomize (QH101=51) QH101_51 "Source of drinking water: Rainwater".
*ichotomize (QH101=61) QH101_61 "Source of drinking water: Tanker truck".
*ichotomize (QH101=71) QH101_71 "Source of drinking water: Cart with small tank".
dichotomize (QH101=81) QH101_81 "Source of drinking water: Surface water (river/dam/lake/pond/stream/canal/irrigation channel)".
dichotomize (QH101=91) QH101_91 "Source of drinking water: Bottled water".
dichotomize (QH101=92) QH101_92 "Source of drinking water: Sachet water".
dichotomize (QH101=93) QH101_93 "Source of drinking water: Water kiosk".
dichotomize (QH101=96 or QH101 = 61) QH101_96 "Source of drinking water: Other/tanker truck".


* Type of toilet facility.
dichotomize (QH109=11) QH109_11 "Type of toilet facility: Flush to piped sewer system".
dichotomize (QH109=12) QH109_12 "Type of toilet facility: Flush to septic tank".
dichotomize (QH109=13) QH109_13 "Type of toilet facility: Flush to pit latrine".
dichotomize (QH109=14 or QH109=15) QH109_14 "Type of toilet facility: Flush to somewhere else".
*ichotomize (QH109=15) QH109_15 "Type of toilet facility: Flush, don't know where".
dichotomize (QH109=21) QH109_21 "Type of toilet facility: Ventilated improved pit latrine".
dichotomize (QH109=22) QH109_22 "Type of toilet facility: Pit latrine with slab".
dichotomize (QH109=23) QH109_23 "Type of toilet facility: Pit latrine without slab/open pit".
*ichotomize (QH109=31) QH109_31 "Type of toilet facility: Composting toilet".
*ichotomize (QH109=41) QH109_41 "Type of toilet facility: Bucket toilet".
*ichotomize (QH109=51) QH109_51 "Type of toilet facility: Hanging toilet/hanging latrine".
dichotomize (QH109=61) QH109_61 "Type of toilet facility: No facility/bush/field".
dichotomize (QH109=96 or QH109 = 31 or QH109=51) QH109_96 "Type of toilet facility: Other/composting toilet, hanging toilet/hanging latrine".

shared_fac QH109_11 QH109_11_sh "Type of toilet facility: Flush to piped sewer system - shared".
shared_fac QH109_12 QH109_12_sh "Type of toilet facility: Flush to septic tank - shared".
shared_fac QH109_13 QH109_13_sh "Type of toilet facility: Flush to pit latrine - shared".
shared_fac QH109_14 QH109_14_sh "Type of toilet facility: Flush to somewhere else - shared".
*hared_fac QH109_15 QH109_15_sh "Type of toilet facility: Flush, don't know where - shared".
shared_fac QH109_21 QH109_21_sh "Type of toilet facility: Ventilated improved pit latrine - shared".
shared_fac QH109_22 QH109_22_sh "Type of toilet facility: Pit latrine with slab - shared".
shared_fac QH109_23 QH109_23_sh "Type of toilet facility: Pit latrine without slab/open pit - shared".
*hared_fac QH109_31 QH109_31_sh "Type of toilet facility: Composting toilet - shared".
*hared_fac QH109_41 QH109_41_sh "Type of toilet facility: Bucket toilet - shared".
*hared_fac QH109_51 QH109_51_sh "Type of toilet facility: Hanging toilet/hanging latrine - shared".
shared_fac QH109_96 QH109_96_sh "Type of toilet facility: Other - shared".


* Type of cookstove.
dichotomize (QH117=1 or QH117=2) QH117_1 "Type of cookstove: Electric stove or solar cooker".
*ichotomize (QH117=2) QH117_2 "Type of cookstove: Solar cooker".
dichotomize (QH117=3) QH117_3 "Type of cookstove: Liquefied petroleum gas (LPG)/cooking gas stove".
dichotomize (QH117=4) QH117_4 "Type of cookstove: Piped natural gas stove".
dichotomize (QH117=5) QH117_5 "Type of cookstove: Biogas stove".
*ichotomize (QH117=6) QH117_6 "Type of cookstove: Liquid fuel stove".
dichotomize (QH117=7) QH117_7 "Type of cookstove: Manufactured solid fuel stove/Brazier".
dichotomize (QH117=8) QH117_8 "Type of cookstove: Traditional solid fuel stove".
dichotomize (QH117=9) QH117_9 "Type of cookstove: Three stone stove/open fire".
dichotomize (QH117=95) QH117_95 "Type of cookstove: No food cooked in household".
*ichotomize (QH117=96) QH117_96 "Type of cookstove: Other".


* Type of cooking fuel.
*ichotomize (QH120=1) QH120_1 "Type of cooking fuel: Alcohol/ethanol".
*ichotomize (QH120=2) QH120_2 "Type of cooking fuel: Gasoline/diesel".
*ichotomize (QH120=3) QH120_3 "Type of cooking fuel: Kerosene/paraffin".
*ichotomize (QH120=4) QH120_4 "Type of cooking fuel: Coal/lignite".
dichotomize (QH120=5 or QH120=4) QH120_5 "Type of cooking fuel: Charcoal, coal/ignite".
dichotomize (QH120=6) QH120_6 "Type of cooking fuel: Wood".
dichotomize (QH120=7 or QH120=8) QH120_7 "Type of cooking fuel: Straw/shrubs/grass or agricultural crop".
*ichotomize (QH120=8) QH120_8 "Type of cooking fuel: Agricultural crop".
*ichotomize (QH120=9) QH120_9 "Type of cooking fuel: Animal dung/waste".
dichotomize (QH120=10) QH120_10 "Type of cooking fuel: Processed biomass (pellets) or woodchips".
*ichotomize (QH120=11) QH120_11 "Type of cooking fuel: Garbage/plastic".
*ichotomize (QH120=12) QH120_12 "Type of cooking fuel: Sawdust".
dichotomize (QH120=96 or QH120 = 2 or QH120 =9) QH120_96 "Type of cooking fuel: Other/animal dung/waste".


* Heat source for home.
dichotomize (QH123=1) QH123_1 "Heat source for home: Central heating".
dichotomize (QH123=2) QH123_2 "Heat source for home: Manufactured space heater".
dichotomize (QH123=3) QH123_3 "Heat source for home: Traditional space heater".
dichotomize (QH123=4) QH123_4 "Heat source for home: Manufactured cookstove/Brazier".
dichotomize (QH123=5) QH123_5 "Heat source for home: Traditional cookstove".
dichotomize (QH123=6) QH123_6 "Heat source for home: Air condition unit".
dichotomize (QH123=7) QH123_7 "Heat source for home: Three stone stove/open fire".
dichotomize (QH123=95) QH123_95 "Heat source for home: No space heating in household".
*ichotomize (QH123=96) QH123_96 "Heat source for home: Other".


* Type of fuel for home heat.
dichotomize (QH125=1) QH125_1 "Type of fuel for home heat: Electricity".
*ichotomize (QH125=2) QH125_2 "Type of fuel for home heat: Piped natural gas".
dichotomize (QH125=3) QH125_3 "Type of fuel for home heat: Solar air heater".
*ichotomize (QH125=4 ) QH125_4 "Type of fuel for home heat: Liquefied petroleum gas (LPG)/cooking gas".
*ichotomize (QH125=5) QH125_5 "Type of fuel for home heat: Biogas".
dichotomize (QH125=6 ) QH125_6 "Type of fuel for home heat: Alcohol/ethanol".
dichotomize (QH125=7 or QH125=8 or QH125=4 or QH125 =5) QH125_7 "Type of fuel for home heat: Gasoline/diesel, Kerosene/parafinn Liquefied petroleum gas (LPG)/cooking gas, biogas".
*ichotomize (QH125=8) QH125_8 "Type of fuel for home heat: Kerosene/paraffin".
*ichotomize (QH125=9) QH125_9 "Type of fuel for home heat: Coal/lignite".
dichotomize (QH125=10 or QH125=9) QH125_10 "Type of fuel for home heat: Charcoal".
dichotomize (QH125=11) QH125_11 "Type of fuel for home heat: Wood".
dichotomize (QH125=12 or QH125=13 or QH125=15) QH125_12 "Type of fuel for home heat: Straw/shrubs/grass, agricultural corp, rocessed biomass/woodchips".
*ichotomize (QH125=13) QH125_13 "Type of fuel for home heat: Agricultural crop".
*ichotomize (QH125=14) QH125_14 "Type of fuel for home heat: Animal dung/waste".
*ichotomize (QH125=15) QH125_15 "Type of fuel for home heat: Processed biomass (pellets) or woodchips".
*ichotomize (QH125=16) QH125_16 "Type of fuel for home heat: Garbage/plastic".
*ichotomize (QH125=17) QH125_17 "Type of fuel for home heat: Sawdust".
*ichotomize (QH125=96) QH125_96 "Type of fuel for home heat: Other".


* Type of light at home.
dichotomize (QH126=1) QH126_1 "Type of light at home: Electricity".
dichotomize (QH126=2) QH126_2 "Type of light at home: Solar lantern".
dichotomize (QH126=3) QH126_3 "Type of light at home: Rechargeable flashlight, torch, or lantern".
dichotomize (QH126=4) QH126_4 "Type of light at home: Battery powered flashlight, torch or lantern".
*chotomize (QH126=5) QH126_5 "Type of light at home: Biogas lamp".
dichotomize (QH126=6 or QH126 = 7 or QH126=13) QH126_6 "Type of light at home: Gasoline lamp or kerosene/paraffin lamp or oil lamp".
*ichotomize (QH126=7) QH126_7 "Type of light at home: Kerosene or paraffin lamp".
dichotomize (QH126=8) QH126_8 "Type of light at home: Charcoal".
dichotomize (QH126=9) QH126_9 "Type of light at home: Wood".
dichotomize (QH126=10 or QH126=12 ) QH126_10 "Type of light at home: Straw/shrubs/grass/animal dung/waste".
*ichotomize (QH126=11) QH126_11 "Type of light at home: Agricultural crop".
*ichotomize (QH126=12) QH126_12 "Type of light at home: Animal dung/waste".
*ichotomize (QH126=13) QH126_13 "Type of light at home: Oil lamp".
dichotomize (QH126=14) QH126_14 "Type of light at home: Candle".
dichotomize (QH126=95) QH126_95 "Type of light at home: No lighting in household".
dichotomize (QH126=96 or QH126=12) QH126_96 "Type of light at home: Other, animal dung/waste".


* Traditional cattle.
if (missing(QH129A) | QH128 <> 1) QH129A=0.
missing values QH129A (99).
compute QH129A_1 = (QH129A >= 1 & QH129A <= 4).
compute QH129A_2 = (QH129A >= 5 & QH129A <= 9).
compute QH129A_3 = (QH129A >= 10 & QH129A <= 98).
variable labels QH129A_1 'Traditional cattle: 1-4' /QH129A_2 'Traditional cattle: 5-9' /QH129A_3 'Traditional cattle: 10+'.


* Dairy cattle.
if (missing(QH129B) | QH128 <> 1) QH129B=0.
missing values QH129B (99).
compute QH129B_1 = (QH129B >= 1 & QH129B <= 4).
compute QH129B_2 = (QH129B >= 5 & QH129B <= 98).
*ompute QH129B_3 = (QH129B >= 10 & QH129B <= 98).
variable labels QH129B_1 'Dairy cattle: 1-4' /QH129B_2 'Dairy cattle: 5+'.


* Horses/donkeys/mules.
if (missing(QH129C) | QH128 <> 1) QH129C=0.
missing values QH129C (99).
compute QH129C_1 = (QH129C >= 1 & QH129C <= 4).
compute QH129C_2 = (QH129C >= 5 & QH129C <= 9).
*ompute QH129C_3 = (QH129C >= 10 & QH129C <= 98).
variable labels QH129C_1 'Horses/donkeys/mules: 1-4' /QH129C_2 'Horses/donkeys/mules: 5+'.


* Beef cattle.
if (missing(QH129D) | QH128 <> 1) QH129D=0.
missing values QH129D (99).
compute QH129D_1 = (QH129D >= 1 & QH129D <= 4).
compute QH129D_2 = (QH129D >= 5 & QH129D <= 98).
*ompute QH129D_3 = (QH129D >= 10 & QH129D <= 98).
variable labels QH129D_1 'Beef cattle: 1-4' /QH129D_2 'Beef cattle: 5+'.


* Goats.
if (missing(QH129E) | QH128 <> 1) QH129E=0.
missing values QH129E (99).
compute QH129E_1 = (QH129E >= 1 & QH129E <= 4).
compute QH129E_2 = (QH129E >= 5 & QH129E <= 9).
compute QH129E_3 = (QH129E >= 10 & QH129E <= 98).
variable labels QH129E_1 'Goats: 1-4' /QH129E_2 'Goats: 5-9' /QH129E_3 'Goats: 10+'.


* Sheep.
if (missing(QH129F) | QH128 <> 1) QH129F=0.
missing values QH129F (99).
compute QH129F_1 = (QH129F >= 1 & QH129F <= 4).
compute QH129F_2 = (QH129F >= 5 & QH129F <= 9).
compute QH129F_3 = (QH129F >= 10 & QH129F <= 98).
variable labels QH129F_1 'Sheep: 1-4' /QH129F_2 'Sheep: 5-9' /QH129F_3 'Sheep: 10+'.


* Chickens.
if (missing(QH129G) | QH128 <> 1) QH129G=0.
missing values QH129G (99).
compute QH129G_1 = (QH129G >= 1 & QH129G <= 9).
compute QH129G_2 = (QH129G >= 10 & QH129G <= 29).
compute QH129G_3 = (QH129G >= 30 & QH129G <= 98).
variable labels QH129G_1 'Chickens: 1-9' /QH129G_2 'Chickens: 10-29' /QH129G_3 'Chickens: 30+'.


* Pigs.
if (missing(QH129H) | QH128 <> 1) QH129H=0.
missing values QH129H (99).
compute QH129H_1 = (QH129H >= 1 & QH129H <= 4).
compute QH129H_2 = (QH129H >= 5 & QH129H <= 9).
compute QH129H_3 = (QH129H >= 10 & QH129H <= 98).
variable labels QH129H_1 'Pigs: 1-4' /QH129H_2 'Pigs: 5-9' /QH129H_3 'Pigs: 10+'.


* Rabbits/other poultry.
if (missing(QH129I) | QH128 <> 1) QH129I=0.
missing values QH129I (99).
compute QH129I_1 = (QH129I >= 1 & QH129I <= 4).
compute QH129I_2 = (QH129I >= 5 & QH129I <= 9).
compute QH129I_3 = (QH129I >= 10 & QH129I <= 98).
variable labels QH129I_1 'Rabbits/other poultry: 1-4' /QH129I_2 'Rabbits/other poultry: 5-9' /QH129I_3 'Rabbits/other poultry: 10+'.


* Size of agricultural land: size.
compute landarea = 0.
if (QH131U = 1) landarea = QH131N*4. /* Hectare = 10000 sq. meters */
if (QH131U = 2) landarea = QH131N*  1.6184. /* 4046.86 sq meters    */
if (QH131U = 3) landarea = QH131N. /* lima 2500sq meters  */
if (QH131U = 9 and QH131N = 9999.5) landarea = 950000.
if (QH131U >= 8) landarea = 0.
if (missing(QH131N) | QH131N >= 9999.8) landarea=999999.
if (missing(QH130 ) | QH130 <> 1) landarea=0.
missing values landarea (999999).


* Electricity.
no2zero QH132A.
* Radio.
no2zero QH132B.
* Television.
no2zero QH132C.
* Telephone (non-mobile).
no2zero QH132D.
* Computer.
no2zero QH132E.
* Refrigerator.
no2zero QH132F.
* Access to internet.
no2zero QH132G.
* Bed.
no2zero QH132H.
* Table.
no2zero QH132I.
* Sofa.
no2zero QH132J.
* Washing machine.
no2zero QH132K.
* Air conditioner.
no2zero QH132L.
* Generator.
no2zero QH132M.
* Microwave.
no2zero QH132N.
* Geyser (water heater).
no2zero QH132O.
* Grain grinder.
no2zero QH132P.
* Plough.
no2zero QH132Q.
* Tractor.
no2zero QH132R.
* Hammer mill.
no2zero QH132S.
* Watch.
no2zero QH133A.
* Bicycle.
no2zero QH133C.
* Motorcycle or scooter.
no2zero QH133D.
* Animal-drawn cart.
no2zero QH133E.
* Car or Truck.
no2zero QH133F.
* Boat with a motor.
no2zero QH133G.
* Banana boat.
no2zero QH133H.
* Canoe.
no2zero QH133I.

* Main floor material.
dichotomize (QH152=11) QH152_11 "Main floor material: Earth/sand".
dichotomize (QH152=12) QH152_12 "Main floor material: Dung".
dichotomize (QH152=21) QH152_21 "Main floor material: Wood planks".
dichotomize (QH152=22) QH152_22 "Main floor material: Palm/bamboo/leeds".
dichotomize (QH152=31) QH152_31 "Main floor material: Parquet or polished wood".
dichotomize (QH152=32) QH152_32 "Main floor material: Vinyl or asphalt strips".
dichotomize (QH152=33) QH152_33 "Main floor material: Ceramic/terrazzo tiles".
dichotomize (QH152=34) QH152_34 "Main floor material: Cement".
dichotomize (QH152=35) QH152_35 "Main floor material: Carpet".
dichotomize (QH152=96) QH152_96 "Main floor material: Other".


* Main roof material.
dichotomize (QH153=11) QH153_11 "Main roof material: No roof".
dichotomize (QH153=12) QH153_12 "Main roof material: Thatch/palm leaf".
*ichotomize (QH153=13) QH153_13 "Main roof material: Sod".
dichotomize (QH153=21 or QH153=22 ) QH153_21 "Main roof material: Rustic mat, Palm/bamboo".
*ichotomize (QH153=22) QH153_22 "Main roof material:  rustic mat".
dichotomize (QH153=23) QH153_23 "Main roof material: Wood planks".
*ichotomize (QH153=24) QH153_24 "Main roof material: Cardboard".
dichotomize (QH153=31) QH153_31 "Main roof material: Metal/iron sheet".
dichotomize (QH153=32) QH153_32 "Main roof material: Wood".
dichotomize (QH153=33) QH153_33 "Main roof material: Calamine/cement fiber".
dichotomize (QH153=34) QH153_34 "Main roof material: Ceramic tiles/harvey tiles".
dichotomize (QH153=35) QH153_35 "Main roof material: Cement".
dichotomize (QH153=36) QH153_36 "Main roof material: Roofing shingles".
*ichotomize (QH153=37) QH153_37 "Main roof material: Mud tiles".
dichotomize (QH153=38) QH153_38 "Main roof material: Asbestos".
dichotomize (QH153=96 or QH153=24 or QH153=37) QH153_96 "Main roof material: Other, cardboard, mud tiles".


* Main wall material.
dichotomize (QH154=11) QH154_11 "Main wall material: No walls".
dichotomize (QH154=12) QH154_12 "Main wall material: Cane/palm/trunks".
dichotomize (QH154=13) QH154_13 "Main wall material: Dirt (mud)".
dichotomize (QH154=21) QH154_21 "Main wall material: Bamboo with mud".
dichotomize (QH154=22) QH154_22 "Main wall material: Stone with mud".
dichotomize (QH154=23) QH154_23 "Main wall material: Uncovered adobe".
dichotomize (QH154=24) QH154_24 "Main wall material: Plywood".
dichotomize (QH154=25) QH154_25 "Main wall material: Cardboard".
dichotomize (QH154=26) QH154_26 "Main wall material: Reused wood".
dichotomize (QH154=27) QH154_27 "Main wall material: Mudbrick".
dichotomize (QH154=31) QH154_31 "Main wall material: Cement".
dichotomize (QH154=32) QH154_32 "Main wall material: Stone with lime/cement".
dichotomize (QH154=33) QH154_33 "Main wall material: Burned bricks".
dichotomize (QH154=34) QH154_34 "Main wall material: Cement blocks".
dichotomize (QH154=35) QH154_35 "Main wall material: Covered adobe".
dichotomize (QH154=36) QH154_36 "Main wall material: Wood planks/shingles".
dichotomize (QH154=96) QH154_96 "Main wall material: Other".

*{Members per sleeping room}.
if (hhusual=0) hhusual=hhslept.
if (QH127>0) memsleep=trunc(hhusual/QH127).
if (QH127=0) memsleep=hhusual.
if (missing(QH127) or QH127>=99 or memsleep>=98) memsleep=99.
variable labels memsleep 'Number of members per sleeping room'.
value labels memsleep 0 'Less than 1 per room'.
formats memsleep (f2.0).
missing values memsleep (99).

* Compute urban and rural variables coded (1/0) for filters later.
compute urban=(QHTYPE = 1).
compute rural=(QHTYPE = 2).
variable labels urban 'Urban' / rural 'Rural'.
value labels urban 1 'Urban' / rural 1 'Rural'.
formats urban rural (f1.0).

execute.

* Check on indicator variable creation.
frequencies variables=QHTYPE to land.

* Toilet facility by shared/not shared.
crosstabs /tables=QH109 by QH110.

* Land area by units - if there are separate units - need to convert them to one unit.
*crosstabs /tables=QH131N by QH131U.

*variables that are not used QH101_71 QH101_61 QH109_15 QH109_15_sh QH109_31 QH109_41 QH109_51 QH109_51  QH117_96 QH117_2 QH117_6 QH120_1 QH120_2 QH120_3 QH120_4 QH120_8 QH120_9 QH120_11 QH120_12   
* QH125_2 QH125_4 QH125_5 QH125_8 QH125_9 QH125_13  QH125_14 QH125_15 QH125_16 QH125_17  QH126_5 QH126_11 QH126_12 QH126_13 QH126_7 QH129B_3 QH129C_3 QH129D_3 QH153_13 QH153_22 QH153_24 QH153_37

frequencies variables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91 QH101_92 QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh  QH109_21_sh QH109_22_sh QH109_23_sh   QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5  QH117_7 QH117_8 QH117_9 QH117_95 
  QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7   QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  QH129A_1 QH129A_2 QH129A_3 QH129B_1 QH129B_2 
  QH129C_1 QH129C_2  QH129D_1 QH129D_2 
  QH129E_1 QH129E_2 QH129E_3 QH129F_1 QH129F_2 QH129F_3
  QH129G_1 QH129G_2 QH129G_3 QH129H_1 QH129H_2 QH129H_3
  QH129I_1 QH129I_2 QH129I_3 landarea
.

* Turn off weights before all factor analysis.
weight off.

* Name the dataset window for the HH data for use later.
dataset name assets.

save outfile='assets.sav'.


*** Test Factor Analysis.
filter off.
execute.

factor /variables
   QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91 QH101_92 QH101_93 QH101_96 
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh  QH109_21_sh QH109_22_sh QH109_23_sh   QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5   QH117_7 QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  QH129A_1 QH129A_2 QH129A_3 QH129B_1 QH129B_2 
  QH129C_1 QH129C_2  QH129D_1 QH129D_2 
  QH129E_1 QH129E_2 QH129E_3 QH129F_1 QH129F_2 QH129F_3
  QH129G_1 QH129G_2 QH129G_3 QH129H_1 QH129H_2 QH129H_3
  QH129I_1 QH129I_2 QH129I_3 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91 QH101_92 QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh  QH109_21_sh QH109_22_sh QH109_23_sh  QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5 QH117_7   QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  QH129A_1 QH129A_2 QH129A_3 QH129B_1 QH129B_2 
  QH129C_1 QH129C_2  QH129D_1 QH129D_2 
  QH129E_1 QH129E_2 QH129E_3 QH129F_1 QH129F_2 QH129F_3
  QH129G_1 QH129G_2 QH129G_3 QH129H_1 QH129H_2 QH129H_3
  QH129I_1 QH129I_2 QH129I_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /method=correlation.


*** Common Factor analysis ***.
** Removed area-specific variables **.
** Agricultural animal variables excluded
** Land area excluded

*** Common Factor Analysis.
filter off.
execute.

factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91 QH101_92 QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh  QH109_21_sh QH109_22_sh QH109_23_sh   QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5 QH117_7  QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91 QH101_92 QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh  QH109_21_sh QH109_22_sh QH109_23_sh   QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5 QH117_7  QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL com)
  /method=correlation.


*** Urban Factor Analysis removed QH154_11 and QH154_26 QH125_12.
filter off.
filter by urban.
execute.


factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91 QH101_92 QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh  QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5  QH117_7 QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11    
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
   QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25  QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91 QH101_92 QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh  QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5 QH117_7  QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11    
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL urb)
  /method=correlation.


*** Rural Factor Analysis taking out QH101_92 and QH153_33.
filter off.
filter by rural.
execute.

factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91  QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh  QH109_21_sh QH109_22_sh QH109_23_sh  QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5  QH117_7 QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32  QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  QH129A_1 QH129A_2 QH129A_3 QH129B_1 QH129B_2 
  QH129C_1 QH129C_2  QH129D_1 QH129D_2 
  QH129E_1 QH129E_2 QH129E_3 QH129F_1 QH129F_2 QH129F_3
  QH129G_1 QH129G_2 QH129G_3 QH129H_1 QH129H_2 QH129H_3
  QH129I_1 QH129I_2 QH129I_3 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_81 QH101_91  QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh   QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5  QH117_7 QH117_8 QH117_9 QH117_95 
    QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10   QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32  QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  QH129A_1 QH129A_2 QH129A_3 QH129B_1 QH129B_2 
  QH129C_1 QH129C_2  QH129D_1 QH129D_2 
  QH129E_1 QH129E_2 QH129E_3 QH129F_1 QH129F_2 QH129F_3
  QH129G_1 QH129G_2 QH129G_3 QH129H_1 QH129H_2 QH129H_3
  QH129I_1 QH129I_2 QH129I_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL rur)
  /method=correlation.


* Label the created score variables.
rename variables (com1 urb1 rur1=comscore urbscore rurscore).
variable labels comscore 'Common wealth score' /urbscore 'Urban wealth score' /rurscore 'Rural wealth score'.

* Add a variable used for linking later.
filter off.
string rowtype_ (A8).
compute rowtype_ = 'EST'.


* Calculate regressions.
** Area=urban.
filter off.
filter by urban.
execute.

* Declare a dataset to be written to in the regression.
dataset declare urbancorv.
* Run regression of comscore with urbscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter urbscore
  /outfile=corv(urbancorv).

* Activate file of output from regression.
dataset activate urbancorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=urbconst urbscore=urbcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = urbancorv
  /by ROWTYPE_.
execute.


* Calculate regressions.
** Area=rural.
filter off.
filter by rural.
execute.

* Declare a dataset to be written to in the regression.
dataset declare ruralcorv.
* Run regression of comscore with rurscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter rurscore
  /outfile=corv(ruralcorv).

* Activate file of output from regression.
dataset activate ruralcorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=rurconst rurscore=rurcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = ruralcorv
  /by ROWTYPE_.
execute.


dataset close urbancorv.
dataset close ruralcorv.
dataset activate assets.
filter off.


*** Calculate combined wealth score from Urban and Rural Scores.
* Use coefficients from urban and rural regressions above.
compute combscor=0.
print formats combscor (f11.5).
write formats combscor (f11.5).
** Urban.
if (urban = 1) combscor=urbconst+urbcoeff*urbscore.
** Rural.
if (rural = 1) combscor=rurconst+rurcoeff*rurscore.
variable labels combscor 'Combined national wealth score'.
execute.


compute hhwt = QHWEIGHT/1000000.
variable labels hhwt 'HH weights'.
formats hhwt (f12.6).
weight by hhwt.

filter off.
execute.

frequencies variables=combscor comscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by urban.
execute.

frequencies variables=combscor urbscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by rural.
execute.

frequencies variables=combscor rurscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
execute.


*Calculate quintiles and scores for data file.
compute hhmemwt=QHWEIGHT*hhusual/1000000.
variable labels hhmemwt 'HH members weighting for index'.
formats hhmemwt (f12.6).
weight by hhmemwt.

filter off.
filter by urban.
execute.

rank variables=urbscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
filter by rural.
execute.

rank variables=rurscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
execute.

rank variables=combscor (A) /rank /ntiles (5) /print=yes /ties=mean.

variable labels ncombsco 'Combined wealth index' /nurbscor 'Urban wealth index' /nrurscor 'Rural wealth index'.
value labels ncombsco nurbscor nrurscor 1 'Lowest' 2 'Second' 3 'Middle' 4 'Fourth' 5 'Highest'.

*** Check on quintiles.
frequencies variables=ncombsco nurbscor nrurscor.


weight by hhwt.

ctables /table (
  QH101_11+QH101_12+QH101_13+QH101_14+QH101_21+QH101_31+QH101_32+QH101_41+QH101_42+QH101_51+QH101_81+QH101_91+QH101_92+QH101_93+QH101_96+
  QH109_11+QH109_12+QH109_13+QH109_14+QH109_21+QH109_22+QH109_23+QH109_61+QH109_96+
  QH109_11_sh+QH109_12_sh+QH109_13_sh+QH109_14_sh+QH109_21_sh+QH109_22_sh+QH109_23_sh+QH109_96_sh+
  QH117_1+QH117_3+QH117_4+QH117_5+QH117_7+QH117_8+QH117_9+QH117_95+
 QH120_5+QH120_6+QH120_7+QH120_10+QH120_96+
  QH123_1+QH123_2+QH123_3+QH123_4+QH123_5+QH123_6+QH123_7+QH123_95+
  QH125_1+QH125_3+QH125_6+QH125_7+QH125_10+QH125_11+QH125_12+
  QH126_1+QH126_2+QH126_3+QH126_4+QH126_6+QH126_8+QH126_9+QH126_10+QH126_14+QH126_95+QH126_96+
  QH132A+QH132B+QH132C+QH132D+QH132E+QH132F+QH132G+QH132H+QH132I+QH132J+QH132K+QH132L+QH132M+QH132N+QH132O+QH132P+QH132Q+QH132R+QH132S+QH133A+QH133C+QH133D+
  QH133E+QH133F+QH133G+QH133H+QH133I+MOBPHONE+CHECKACC+
  QH152_11+QH152_12+QH152_21+QH152_22+QH152_31+QH152_32+QH152_33+QH152_34+QH152_35+QH152_96+
  QH153_11+QH153_12+QH153_21+QH153_23+QH153_31+QH153_32+QH153_33+QH153_34+QH153_35+QH153_36+QH153_38+QH153_96+
  QH154_11+QH154_12+QH154_13+QH154_21+QH154_22+QH154_23+QH154_24+QH154_25+QH154_26+QH154_27+QH154_31+QH154_32+QH154_33+QH154_34+QH154_35+QH154_36+QH154_96+
  HOUSE+LAND+memsleep+
  QH129A_1+QH129A_2+QH129A_3+QH129B_1+QH129B_2+
  QH129C_1+QH129C_2+QH129D_1+QH129D_2+
  QH129E_1+QH129E_2+QH129E_3+QH129F_1+QH129F_2+QH129F_3+
  QH129G_1+QH129G_2+QH129G_3+QH129H_1+QH129H_2+QH129H_3+
  QH129I_1+QH129I_2+QH129I_3+landarea 
  )[S][Mean F8.3] by (ncombsco+nurbscor+nrurscor)[C]
  /slabels visible=no.

* Alternative instead of ctables.
*means tables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51  QH101_81 QH101_91 QH101_92 QH101_93 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14  QH109_21 QH109_22 QH109_23  QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh  QH109_21_sh QH109_22_sh QH109_23_sh   QH109_96_sh
  QH117_1  QH117_3 QH117_4 QH117_5  QH117_7 QH117_8 QH117_9 QH117_95 
  QH120_2  QH120_5 QH120_6 QH120_7 QH120_10  QH120_96
  QH123_1 QH123_2 QH123_3 QH123_4 QH123_5 QH123_6 QH123_7 QH123_95 
  QH125_1  QH125_3   QH125_6 QH125_7  QH125_10 QH125_11 QH125_12   
  QH126_1 QH126_2 QH126_3 QH126_4  QH126_6  QH126_8 QH126_9 QH126_10    QH126_14 QH126_95 QH126_96
  QH132A QH132B QH132C QH132D QH132E QH132F QH132G QH132H QH132I QH132J QH132K QH132L QH132M QH132N QH132O QH132P QH132Q QH132R QH132S QH133A QH133C QH133D
  QH133E QH133F QH133G QH133H QH133I MOBPHONE CHECKACC
  QH152_11 QH152_12 QH152_21 QH152_22 QH152_31 QH152_32 QH152_33 QH152_34 QH152_35 QH152_96
  QH153_11 QH153_12  QH153_21  QH153_23  QH153_31 QH153_32 QH153_33 QH153_34 QH153_35 QH153_36  QH153_38 QH153_96
  QH154_11 QH154_12 QH154_13 QH154_21 QH154_22 QH154_23 QH154_24 QH154_25 QH154_26 QH154_27 QH154_31 QH154_32 QH154_33 QH154_34 QH154_35 QH154_36 QH154_96
  HOUSE LAND memsleep
  QH129A_1 QH129A_2 QH129A_3 QH129B_1 QH129B_2 
  QH129C_1 QH129C_2  QH129D_1 QH129D_2
  QH129E_1 QH129E_2 QH129E_3 QH129F_1 QH129F_2 QH129F_3
  QH129G_1 QH129G_2 QH129G_3 QH129H_1 QH129H_2 QH129H_3
  QH129I_1 QH129I_2 QH129I_3 landarea
    by ncombsco nurbscor nrurscor
  /cells mean count stddev.


graph /histogram(normal)=combscor /title= 'Distribution of Households by Wealth Scores'.
frequencies variables=combscor
  /format=notable
  /ntiles=5
  /statistics=stddev minimum maximum semean mean median mode skewness seskew kurtosis sekurt
  /order=analysis.


weight off.
filter off.
write formats combscor urbscore rurscore (f11.5).

* Save final dataset of assets.
save outfile='assets.sav'.

*** Write out scores file.
write outfile='scores.dat' table /QHCLUST QHNUMBER combscor ncombsco urbscore nurbscor rurscore nrurscor.
execute.

* Produce table 2.6 weighted by de jure population to test.
weight by hhmemwt.
compute total = 0.
variable labels total 'Total'.
value labels total 0 ' '.
ctables /vlabels variables=QHTYPE QHPROVIN total Ncombsco display=both
  /table QHTYPE [C] + QHPROVIN [C] + total [C] BY Ncombsco [C][rowpct.count '%' F8.1, totals [rowpct.count '%' F8.1, count '' F8.0]]
  /categories variables=Ncombsco total=yes
  /titles title='Table 2.6 Wealth Quintiles' ''
    'Percent distribution of the de jure population by wealth quintiles, according to residence and region, Zambia DHS 2024'
  corner='Residence/region' /slabels visible=no.